mirror of
https://github.com/funkemunky/AntiVPN.git
synced 2026-05-31 09:31:54 +00:00
Dawson
c95c7b37a1
* Forcing BukkitPlayer#kickPlayer to always run within a main thread context using BukkitRunnable. Bumping version to 1.10.1 * Fixing async kick error, adding condition that allows players to be whitelisted even while they are offline (assuming this is not a cracked server). * Updating gradle piplines and files * correcting startup bug as a result of a packaging issue * Fixing asynchronous run command * Adds a regression test to ensure this doesnt happen again
100 lines
3.0 KiB
Groovy
100 lines
3.0 KiB
Groovy
plugins {
|
|
id 'java'
|
|
id 'com.gradleup.shadow' version '9.4.1'
|
|
}
|
|
|
|
def aggregateTestProjects = [
|
|
project(':Common:Source'),
|
|
project(':Bukkit:Plugin'),
|
|
project(':Bungee:BungeePlugin'),
|
|
project(':Sponge:SpongePlugin'),
|
|
project(':Velocity:VelocityPlugin')
|
|
]
|
|
|
|
allprojects {
|
|
group = 'dev.brighten.antivpn'
|
|
version = '1.10.1'
|
|
|
|
repositories {
|
|
maven { url 'https://repo.papermc.io/repository/maven-public/' }
|
|
maven { url 'https://nexus.funkemunky.cc/repository/papermc-public/' }
|
|
maven { url 'https://nexus.funkemunky.cc/repository/maven-public/' }
|
|
maven { url 'https://nexus.funkemunky.cc/repository/maven-central/' }
|
|
maven { url 'https://nexus.funkemunky.cc/content/repositories/releases/' }
|
|
maven { url 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
|
|
maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
|
|
maven { url 'https://repo.spongepowered.org/repository/maven-public/' }
|
|
maven { url 'https://jitpack.io' }
|
|
}
|
|
|
|
apply plugin: 'java'
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion = JavaLanguageVersion.of(21)
|
|
}
|
|
}
|
|
|
|
tasks.withType(JavaCompile).configureEach {
|
|
options.encoding = 'UTF-8'
|
|
options.compilerArgs << '-XDignore.symbol.file'
|
|
}
|
|
|
|
dependencies {
|
|
compileOnly 'org.projectlombok:lombok:1.18.44'
|
|
annotationProcessor 'org.projectlombok:lombok:1.18.44'
|
|
testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
|
|
testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
|
|
}
|
|
|
|
test {
|
|
useJUnitPlatform()
|
|
systemProperty 'mockito.mockmaker', 'subclass'
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
testImplementation 'org.junit.platform:junit-platform-suite:1.11.4'
|
|
}
|
|
|
|
sourceSets {
|
|
test {
|
|
compileClasspath += files(aggregateTestProjects.collect { it.sourceSets.test.output + it.sourceSets.test.compileClasspath })
|
|
runtimeClasspath += files(aggregateTestProjects.collect { it.sourceSets.test.output + it.sourceSets.test.runtimeClasspath })
|
|
}
|
|
}
|
|
|
|
tasks.named('test') {
|
|
dependsOn(aggregateTestProjects.collect { it.tasks.named('testClasses') })
|
|
jvmArgs("-XX:+EnableDynamicAgentLoading")
|
|
}
|
|
|
|
evaluationDependsOn(':Common:Source')
|
|
evaluationDependsOn(':Bukkit:Loader')
|
|
evaluationDependsOn(':Velocity:VelocityLoader')
|
|
evaluationDependsOn(':Bungee:BungeeLoader')
|
|
|
|
dependencies {
|
|
implementation project(':Bukkit:Loader')
|
|
implementation project(':Velocity:VelocityLoader')
|
|
implementation project(':Bungee:BungeeLoader')
|
|
}
|
|
|
|
shadowJar {
|
|
archiveFileName.set("AntiVPN-${project.version}-universal.jar")
|
|
|
|
// Include the shaded Common:Source jar as a single resource
|
|
from(project(':Common:Source').tasks.shadowJar) {
|
|
rename { 'antivpn-source.jarinjar' }
|
|
}
|
|
}
|
|
|
|
tasks.named('shadowJar') {
|
|
dependsOn(':Common:Source:shadowJar')
|
|
dependsOn(':Bukkit:Loader:shadowJar')
|
|
dependsOn(':Velocity:VelocityLoader:shadowJar')
|
|
dependsOn(':Bungee:BungeeLoader:shadowJar')
|
|
}
|
|
|
|
tasks.build.dependsOn shadowJar
|